从2009年发布至今Win7系统已经服役了10年时间，现在微软满怀结束对Win7系统的技术支持，今后将不再有任何安全漏洞更新！现在微软也在Win7桌面弹窗提示用户这款系统马上就到期了，建议大家升级Win10系统。微软此前已经推送 KB4493132 可选更新，这枚可选更新的作用就是定时在桌面右下角弹窗提醒结束支持的消息。当然很多用户还是会坚持使用Win7，那么如何禁止这个频繁弹出来的提示呢？下面我们可以教大家一个方法彻底禁用。

Win7禁止到期提示方法如下：

1. 点击开始菜单找到运行然后输入RegEdit打开注册表，

2. 打开后展开如下路径：HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\Gwx

3. 右键点击左侧导航窗口的GWX然后选择新建DWORD（32位）值，将其命名为DisableGwx

4. 创建并命名成功后双击DisableGwx将其默认键值修改1并点击确定

5. 继续展开注册表如下路径：HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\WindowsUpdate

6. 右键点击WindowsUpdate选择新建DWORD（32位）值，将其命名为DisableOSUpgrade

7. 创建并命名成功后双击DisableOSUpgrade将其默认键值修改为1并点击确定即可

一般来说，如果你是企业公司用户，数据重要那么建议升级你的系统~毕竟失去了技术支持之后，漏洞无法修复带来的风险还是比较高的，如果普通用户也就是看看电视娱乐一下也就无所谓了。

• 删除提示[你的windows7电脑不受支持].exe所有垃圾批处理脚本
• winsxs清理
• 注册表清理和设置优化
• 任务计划清理和删除相关文件。

  @ECHO OFF
  >NUL 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
  IF '%errorlevel%' NEQ '0' (
  GOTO UACPrompt
  ) ELSE ( GOTO gotAdmin )
  :UACPrompt
  ECHO Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
  ECHO UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
  "%temp%\getadmin.vbs"
  EXIT /B
  :gotAdmin
  IF EXIST "%temp%\getadmin.vbs" ( DEL "%temp%\getadmin.vbs" )
  TITLE EOSNotify-清理  nat.ee
  CLS
  ECHO 网址：nat.ee
  ECHO 荣耀-制作
  ECHO QQ：1800619
  TIMEOUT 3 >NUL
  SET winsxs=%SystemRoot%\winsxs
  ECHO.
  ECHO 清理EOSNotify WinSXS...
  FOR /f %%i IN ('dir /b %winsxs%\^|findstr ".*microsoft-windows-eosnotify.*"') DO (
  takeown /a /r /d Y /f "%winsxs%\%%i" >NUL
  icacls "%winsxs%\%%i" /T /C /grant administrators:D >NUL
  ECHO 正在删除WinSXS
  ECHO %%i
  RMDIR /s /q "%winsxs%\%%i"
  )
  ECHO.
  ECHO 清理EOSNotify manifest...
  FOR /f %%i IN ('dir /b %winsxs%\Manifests^|findstr ".*microsoft-windows-eosnotify.*\.manifest"') DO (
  takeown /a /f "%winsxs%\Manifests\%%i" >NUL
  icacls "%winsxs%\Manifests\%%i" /grant administrators:D >NUL
  DEL /F /S /Q "%winsxs%\Manifests\%%i"
  )
  TIMEOUT 3 >NUL
  ECHO.
  ECHO 删除EOSNotify 注册表...
  FOR /f %%i IN ('REG QUERY HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\SideBySide\Winners^|findstr ".*microsoft-windows-eosnotify.*"') DO (
  ECHO 正在删除注册表
  reg delete %%i /f
  )
  TIMEOUT 3 >NUL
  ECHO.
  ECHO 删除EOSNotify计划任务...
  schtasks /delete /tn "\Microsoft\Windows\Setup\EOSNotify" /f
  schtasks /delete /tn "\Microsoft\Windows\Setup\EOSNotify2" /f
  TIMEOUT 3 >NUL
  IF EXIST "%SystemRoot%\System32\EOSNotify.exe" (
  ECHO.
  ECHO 删除 EOSNotify.exe 文件...
  taskkill /F /IM "%SystemRoot%\System32\EOSNotify.exe" 1>NUL 2>NUL
  takeown /a /f "%SystemRoot%\System32\EOSNotify.exe" >NUL
  icacls "%SystemRoot%\System32\EOSNotify.exe" /grant administrators:D >NUL
  DEL /F /S /Q "%SystemRoot%\System32\EOSNotify.exe"
  )
  IF EXIST "%SystemRoot%\Migration\WTR\EOSNotifyMig.inf" (
  ECHO.
  ECHO 删除 EOSNotifyMig.inf 文件...
  DEL /F /S /Q "%SystemRoot%\Migration\WTR\EOSNotifyMig.inf"
  )
  TIMEOUT 3 >NUL
  ECHO.
  ECHO 优化EOSNotify 注册表设置...
  reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\SipNotify" /v "DontRemindMe" /t REG_DWORD /d "1" /f
  reg add "HKLM\Software\Policies\Microsoft\Windows\Gwx" /v "DisableGwx" /t REG_DWORD /d "1" /f
  reg add "HKLM\Software\Policies\Microsoft\Windows\WindowsUpdate" /v "DisableOSUpgrade" /t REG_DWORD /d "1" /f
  reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\EOSNOTIFY.EXE" /v "Debugger" /t REG_SZ /d "*" /f
  reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\SIPNOTIFY.EXE" /v "Debugger" /t REG_SZ /d "*" /f
  reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\EOSNotify" /v "DiscontinueEOS" /t REG_DWORD /d "1" /f
  reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\EOSNotify" /v "Discontinue" /t REG_DWORD /d "1" /f
  reg delete "HKCU\Software\Microsoft\Windows\CurrentVersion\EOSNotify" /v "LastRunTimestamp" /f
  TIMEOUT 3 >NUL
  ECHO.
  ECHO 按任意键退出……
  PAUSE >NUL
  EXIT