@echo off
set IP=192.168.10.60
set MASK=255.255.255.0
set GATEWAY=192.168.10.3
set DNS1=192.168.10.3
set DNS2=192.168.10.2
set NAME="WLAN"
::set NAME="以太网"
::route delete 0.0.0.0
:::::::::::::::::::::::自动获取IP地址:::::::::::::::::::::::::::::::::::::::
::ECHO.
::netsh interface ip set address %NAME% source=dhcp
::netsh interface ip set dns %NAME% source=dhcp
:::::::::::::::::::::::手动设置固定IP地址:::::::::::::::::::::::::::::::::::
ECHO.
netsh interface ip set address %NAME% source=static %IP% %MASK% %GATEWAY%
::primary只在主 DNS 后缀下注册
netsh interface ip set dns %NAME% source=static addr=%DNS1% primary
netsh interface ip add dns %NAME% addr=%DNS2%
:::::::::::::::::::::::重置路由::::::::::::::::::::::::::::::::::::::::::::
::ECHO.
::route delete 0.0.0.0
::route add  0.0.0.0 mask 0.0.0.0 %GATEWAY%
@echo 网关更改为%GATEWAY%！
pause

静态IP脚本：

在记事本中粘贴以下代码：

netsh interface ip set address name="本地连接" source=static addr=10.101.192.3 mask=255.255.255.0 gateway=10.101.192.1 1
netsh interface ip set dns name="本地连接" source=static addr=202.196.64.1

保存的时候要注意一下，文件名要以.bat结尾，编码为ANSI

• 第一条语句中，ip set address是设置IP地址
• name=“本地连接”是指你用那个连接上网的，每个人的电脑不同，根据自己的情况来修改
• source=static是指，你设置的是静态IP
• addr是指IP地址
• mask指子网掩码
• gateway指默认网关

第二条语句中，ip set dns是指设置DNS服务器地址
addr是首选DNS服务器

动态IP脚本

netsh interface ip set address name="本地连接" source=dhcp
netsh interface ip set dns name="本地连接" source=dhcp

完整版

@echo off
echo.
echo 修改ip地址，1为自动获取ip地址，2为修改家里ip地址,3 为公司IP
echo.set sel=
set/p sel=请选择修改方式：
if "%sel%"=="1" goto auto
if "%sel%"=="2" goto home
if "%sel%"=="3" goto company
echo 您没有选择修改方式。
goto end

:auto
netsh interface ip set address name="无线网络连接" source=dhcp
netsh interface ip delete dns "无线网络连接" all
ipconfig /flushdns
ipconfig /all
goto end

:home
echo 正在更改IP地址，请稍等......
netsh interface ip set address name="无线网络连接" source=static addr=192.168.10.11 mask=255.255.255.0 gateway=192.168.10.1 gwmetric=1
netsh interface ip set dns name="无线网络连接" source=static addr=192.168.10.10
netsh interface ip add dns name="无线网络连接" addr=114.114.114.114 index=2
ipconfig /flushdns
ipconfig /all
echo 更改IP地址完成！
goto end

:company
echo 正在更改IP地址，请稍等......
netsh interface ip set address name="无线网络连接" source=static addr=10.85.10.80 mask=255.255.255.0 gateway=10.85.10.253 gwmetric=1
netsh interface ip set dns name="无线网络连接" source=static addr=218.104.78.2
netsh interface ip add dns name="无线网络连接" addr=10.85.7.100 index=2
ipconfig /flushdns
ipconfig /all
goto end

:end
pause